/////////////////////
// TP1, exercice 1 //
/////////////////////


//Le nombre de pas de discrétisation
N=10;

//Le pas d'espace
dx=1/(N+1);

//La grille d'espace
grille=[0:N+1]'*dx;

//Définition de la matrice du problème
A=-2*diag(ones(1,N))+diag(ones(1,N-1),1)+diag(ones(1,N-1),-1);
A=A/(dx^2);

//Le second membre
f=[1:N]'*dx;

//La solution exacte
x=linspace(0,1,1000);
sol_ex=(x.^3-x)/6;


///////////////////////////////////////////////


//On resoud le schéma numérique
sol_app=A\f;

//On rajoute les conditions au bord
sol_app=[0 ; sol_app ; 0];


//////////////////////////////////////////////


//Tracé de la solution approchée
scf(0);clf();//Une nouvelle fenêtre
plot2d(grille,sol_app,5);//5 = en rouge

//Tracé de la solution exacte
plot2d(x,sol_ex,13);//13 = en vert

//Majoration de l'erreur :
max(sol_app-(grille.^3-grille)/6)


//Pour comparaison, affichage du "zéro machine", c'est-à-dire de
//la précision relative d'un calcul
%eps
//Ici, l'erreur devrait être de l'ordre de
%eps*(0.5^3-0.5)/6
