// TP1 - Exercice 4
// On trace l'histogramme d'une loi binomiale.


// Taille de l'échantillon
N = 100000;


// Paramètres de la loi de Bernoulli
p = 0.4;
n = 30;



X = sum((rand(N,n)<p),'c');
// (rand(N,n)<p) est une matrice de taille (N,n) contenant des
// En utilisant sum(...,'c'), on fait la somme ligne par ligne.
// On obtient donc un vecteur colonne de taille (N,1), dont les
// coefficients sont les sommes de n Bernoullis indépendantes :
// ce sont donc des binomiales de paramètre (n,p).

xset("window",0) // On ouvre la fenêtre n°0
clf()            // On efface la figure

histplot([-0.5:n+0.5],X); // Tracé de l'histogramme. Le vecteur
                          // [-0.5:n+0.5] contient les limites
                          // des classes de l'histogramme.

k = [0:n];
Pk = zeros(k); // Le vecteur Pk va contenir les probabilités P(X=i)
for i = 0:n
  Pk(i+1) = p^i * (1-p)^(n-i) * prod([n-i+1:n])/prod([1:i]);
end

plot(k,Pk,'r'); // 'r' pour 'rouge' (enfin 'red')
